home *** CD-ROM | disk | FTP | other *** search
/ Language/OS - Multiplatform Resource Library / LANGUAGE OS.iso / gnu / smaltalk.lha / smalltalk-1.1.1 / stix / Point.st < prev    next >
Text File  |  1991-09-13  |  4KB  |  230 lines
  1. "=====================================================================
  2. |    Point Class Definitions
  3.  ====================================================================="
  4.  
  5.  
  6. "======================================================================
  7. |
  8. | Copyright (C) 1990, 1991 Free Software Foundation, Inc.
  9. | By Doug McCallum <uunet!ico.isc.com!dougm>
  10. | Additions by sbb@eng.sun.com (Steve Byrne)
  11. |
  12. | This file is part of GNU Smalltalk.
  13. |
  14. | GNU Smalltalk is free software; you can redistribute it and/or modify it
  15. | under the terms of the GNU General Public License as published by the Free
  16. | Software Foundation; either version 1, or (at your option) any later version.
  17. | 
  18. | GNU Smalltalk is distributed in the hope that it will be useful, but WITHOUT
  19. | ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  20. | FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  21. | details.
  22. | 
  23. | You should have received a copy of the GNU General Public License along with
  24. | GNU Smalltalk; see the file COPYING.  If not, write to the Free Software
  25. | Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.  
  26. |
  27.  ======================================================================"
  28.  
  29.  
  30.  
  31.  
  32. "
  33. |     Change Log
  34. | ============================================================================
  35. | Author       Date       Change
  36. | sbb         13 Sep 91      Added = for Points (= from Object isn't right)
  37. |
  38. | dougm      16 Apr 90    Created basic Point class.
  39. |
  40. "
  41.  
  42. Object subclass: #Point
  43.        instanceVariableNames: 'x y'
  44.        classVariableNames: ''
  45.        poolDictionaries: ''
  46.        category: nil !
  47.  
  48. Point comment:
  49. 'Beginning of a Point class for simple display manipulation.  Has not been
  50.  exhaustively tested but appears to work for the basic primitives and for
  51.  the needs of the Rectangle class.' !
  52.  
  53. !Number methodsFor: 'point creation'!
  54.  
  55. @ y
  56.     ^ Point x: self y: y
  57. !
  58.  
  59. asPoint
  60.     ^Point x: self y: self
  61. !!
  62.  
  63.  
  64. !Point class methodsFor: 'instance creation'!
  65.  
  66. x: xInteger y: yInteger
  67.     ^self new x: xInteger y: yInteger
  68. !!
  69.  
  70. !Point methodsFor: 'printing'!
  71.  
  72. printOn: aStream
  73.     x printOn: aStream.
  74.     '@' printOn: aStream.
  75.     y printOn: aStream
  76. !!
  77.  
  78. !Point methodsFor: 'storing'!
  79.  
  80. storeOn: aStream
  81.     x storeOn: aStream.
  82.     '@' storeOn: aStream.
  83.     y storeOn: aStream
  84. !!
  85.  
  86. !Point methodsFor: 'accessing'!
  87.  
  88. x
  89.     ^x
  90. !
  91.  
  92. y
  93.     ^y
  94. !
  95.  
  96. x: aNumber
  97.     x _ aNumber
  98. !
  99.  
  100. y: aNumber
  101.     y _ aNumber
  102. !
  103.  
  104. x: anXNumber y: aYNumber
  105.     x _ anXNumber.
  106.     y _ aYNumber
  107. !!
  108.  
  109. !Point methodsFor: 'converting'!
  110.  
  111. asPoint
  112.     ^self            "But I already AM a point!"
  113. !
  114.  
  115. hash
  116.     ^(x abs + y abs) truncated
  117. !!
  118.  
  119. !Point methodsFor: 'arithmetic'!
  120.  
  121. + delta
  122.     delta _ delta asPoint.
  123.     ^Point x: (x + delta x) y: (y + delta y)
  124. !
  125.  
  126. - delta
  127.     delta _ delta asPoint.
  128.     ^Point x: (x - delta x) y: (y - delta y)
  129. !
  130.  
  131. * scale
  132.     scale _ scale asPoint.
  133.     ^Point x: (x * scale x) y: (y * scale y)
  134. !
  135.  
  136. / scale
  137.     scale _ scale asPoint.
  138.     ^Point x: (x / scale x) y: (y / scale y)
  139. !
  140.  
  141. // scale
  142.     scale _ scale asPoint.
  143.     ^Point x: (x // scale x) y: (y // scale y)
  144. !
  145.  
  146. abs
  147.     ^Point x: (x abs) y: (y abs)
  148. !!
  149.  
  150. !Point methodsFor: 'truncation and round off'!
  151.  
  152. rounded
  153.     ^Point x: (x rounded) y: (y rounded)
  154. !
  155.  
  156. truncateTo: grid
  157.     ^Point x: (x truncateTo: grid) y: (y truncateTo: grid)
  158.  
  159. !!
  160.  
  161.  
  162. !Point methodsFor: 'comparing'!
  163.  
  164. = aPoint
  165.     ^(x = aPoint x) and: [ y = aPoint y ]
  166. !
  167.  
  168. < aPoint
  169.     ^(x < aPoint x) and: [ (y < aPoint y) ]
  170. !
  171.  
  172. > aPoint
  173.     ^(x > aPoint x) and: [ (y > aPoint y) ]
  174. !
  175.  
  176. <= aPoint
  177.     ^(self > aPoint) not    "unverified"
  178. !
  179.  
  180. >= aPoint
  181.     ^(self < aPoint) not    "unverified"
  182. !
  183.  
  184. max: aPoint
  185.     (self >aPoint )
  186.        ifTrue: [ ^self ]
  187.        ifFalse:[ ^aPoint ]
  188. !
  189.  
  190. min: aPoint
  191.     (self < aPoint)
  192.        ifTrue: [^ self ]
  193.        ifFalse:[^ aPoint ]
  194. !!
  195.  
  196. !Point methodsFor: 'point functions'!
  197.  
  198. dist: aPoint
  199.     | a b |
  200.     a _ x - (aPoint x).
  201.     b _ y - (aPoint y).
  202.     ^((a squared) + (b squared)) sqrt
  203. !
  204.  
  205. dotProduct: aPoint
  206.     ^(x * aPoint x) + (y * aPoint y)
  207. !
  208.  
  209. grid: aPoint
  210.     ^Point x: (x roundTo: (aPoint x)) y: (y roundTo: (aPoint y))
  211. !
  212.  
  213. normal
  214. "rotate the Point 90degrees clockwise and get the unit vector"
  215.     |len|
  216.     len _ ((x squared) + (y squared)) sqrt.
  217.     ^Point x: ((y asFloat negated)/len) y: (x/len)
  218. !
  219.  
  220. transpose
  221.     ^Point x: y y: x
  222. !
  223.  
  224. truncatedGrid: aPoint
  225.     ^Point x: (x truncateTo: (aPoint x)) y: (y truncateTo: (aPoint y))
  226. !!
  227.  
  228.  
  229.  
  230.